对于一般交易者，ＣＤＰ这一指标是有着很大用处，它可用于一种极短线的操作，即当日内同时买进卖出。我们先来谈谈其一般的用法：

　　计算方法

　　１．先计算ＣＤＰ值（需求值）

　　ＣＤＰ＝（Ｈ＋Ｌ＋２Ｃ）÷４

　　Ｈ：前一日最高价，Ｌ：前一日最低价，Ｃ：前一日收市价

　　２．计算

　　ＡＨ（最高值）＝ＣＤＰ＋（Ｈ－Ｌ）ＮＨ（近高值）＝ＣＤＰ×２－Ｌ　　ＡＬ（最低值）＝ＣＤＰ－（Ｈ－Ｌ）ＮＬ（近低值）＝ＣＤＰ×２－Ｈ　　则此五个数值的排列顺序为（从最高到最低）：ＡＨ，ＮＨ，ＣＤＰ，ＮＬ，ＡＬ。

　　运用原则

　　找出这五个数值之后，即用前一天的行情波动将当日的未来行情做一个高低等级的划分。分析者可利用这个高低区分来判断当日走势。

　　研判的关键是开市价在ＣＤＰ五个数值的哪个位置，因开市价通常由市场买卖双方心理期望合理价的折衷后形成的，影响当天的走势。

    1.当开盘价高于CDP时，属于强市；当开盘价低于CDP时，属于弱市。

　　2.在波动并不很大的情况下，即开市价处在近高值与近低值之间，通常交易者可以在近低值的价位买进，而在近高期的价位卖出；或在近高值的价位卖出，近低值的价位买进。

　　3.在波动较大的情况下，即开市价开在最高值或最低值附近时，意味着跳空开高或跳空开低，是一个大行情的发动开始。因此，交易者可在最高值的价位去追买，最低值的价位去追卖。通常一个跳空，意味着一个强烈的涨跌，应有相当的利润。（对于大幅高开或低开，已经偏离最高值和最低值有一定距离，则不能按上述操作，如201001111的大盘）

    4.手中持股，股价涨到NH减仓，继续涨到AH继续减仓，有时弱势的时候涨到CDP就可以减仓，直接跳空开在AL附近或者逐步跌破AL不收回则斩仓出局；手中无股，股价跌到NL加仓，继续跌到AL继续加仓，有时强势的时候跌到CDP就可以加仓，直接跳空开在AH附近或者逐步拉高站稳AH则可追入（注意由于股票T+1,买入后跌破AL也只能在次日操作，而卖出后突破AH则可追回）

　　功能分析　　

    １．ＣＤＰ最适合于上下震荡的盘局行情，选择高卖低买的区间赚取短线利润。

　　２．对于大涨大跌的行情，尤其是冲破阻力价和支撑位时，为避免轧空或横压，需设停损点，防止突发性利多或利空的影响。

（对于中长线看好的票，可以拿一部分仓位做短差降成本，当然用cdp测算出来的数值只是一个买卖点的参考，还可以根据压单托单，分时走势做短差降成本）

源码一：(适用大智慧L2，同花顺)

CDP：

PT:=REF(H,1)-REF(L,1);
CDP: (REF(H,1)+REF(L,1)+REF(C,1)*2)/4;
AH: (CDP+PT);
NH: (2*CDP-REF(L,1));
NL: (2*CDP-REF(H,1));
AL: (CDP-PT);

功能描述：该指标在今日收盘的时候无法看到次日的数值，只有在次日开盘时能看到当日的数值

CDP: (REF(H,1)+REF(L,1)+REF(C,1)*2)/4;  说明昨日收盘价是三个价格中最重要的，占的权重大

CDP: (REF(H,1)+REF(L,1)+REF(C,1))/3;    说明昨日的三个价格同样重要

CDP1:

PT:=REF(H,1)-REF(L,1);
CDP: (REF(H,1)+REF(L,1)+REF(C,1))/3;
AH: (CDP+PT);
NH: (2*CDP-REF(L,1));
NL: (2*CDP-REF(H,1));
AL: (CDP-PT);

通常可以把CDP和CDP1相应等级组成的价格区间（以及该区间100%+/-0.5%）作为盘中的买卖区间

源码二：

CDP2：
PT  := HIGH - LOW;
CDP : (HIGH + LOW +2 * CLOSE)/4;
AH  : CDP + PT;
NH  : 2*CDP-LOW;
NL  : 2*CDP-HIGH;
AL  : CDP - PT;

功能描述：该指标只适用在今日收盘后提前测算出明日的值，且今日的收盘价是最重要，当日盘中不适用，需要看前一日的数值

CDP3:
PT  := HIGH - LOW;
CDP : (HIGH + LOW + CLOSE)/3;
AH  : CDP + PT;
NH  : 2*CDP-LOW;
NL  : 2*CDP-HIGH;
AL  : CDP - PT;

功能描述：该指标只适用在今日收盘后提前测算出明日的值，且三个价格同等重要，当日盘中不适用，需要看前一日的数值

通常可以把CDP2和CDP3相应等级组成的价格区间（以及该区间100%+/-0.5%）作为买卖区间

源码三：

CDP加强版：

PT:=REF(H,1)-REF(L,1);
CDP:=(REF(H,1)+REF(L,1)+REF(C,1)*2)/4;
AH:=CDP+PT;
AL:=CDP-PT;
NH:=CDP*2-REF(L,1);
NL:=CDP*2-REF(H,1);
强:IF(AH>REF(C,1)*1.1,REF(C,1)*1.1,AH)NODRAW;
阻:IF(NH>强,(强-CDP)*0.618+CDP,NH)NODRAW,COLORCYAN;
M:=IF(AL<REF(C,1)/1.1,REF(C,1)/1.1,AL);
撑:IF(NL<M,CDP-(CDP-M)*0.618,NL)NODRAW;
底:IF(AL<REF(C,1)/1.1,REF(C,1)/1.1,AL)NODRAW; 

功能描述：考虑到了股票的涨跌停限制，当振幅不大时，数值和CDP是完全一样的；只有当振幅较大时，比如权证或者连续拉涨跌停后大幅震荡，数值和CDP不完全相同或者完全不相同，此时结合两个指标，相当于多了几个等级，多了一个（或两个）支撑位和阻力位，以CDP指标为主，CDP加强指标为辅